Portal    Foro    Buscar    FAQ    Registrarse    Conectarse


Publicar nuevo tema  Responder al tema 
Página 1 de 1
 
 
Añadiendo Nuevas Caracteristicas A Control Fbcolor!
Autor Mensaje
Responder citando   Descargar mensaje  
Mensaje Añadiendo Nuevas Caracteristicas A Control Fbcolor! 
 
Buenas

No se si ya han usado el control fbcolor... sino  es así bajenlo de la Granja Gambas y vean.

reciente mente le agregue la posibilidad de modificar el texto de tooltip de los tres botones, trazo, fondo y reseteo

pero me he dado cuenta que a veces no quiero usar fondo y trazo sino fondo o trazo para eso quiero ocultar el que no quiero usar

para eso he pensado usar una propiedad de tipo intenger  0  seria ver todo
1 seria ver solo trazo
2 seria ver solo fondo, el botón reseteo siempre se vera

la cuestión es como seria declarado en la propiedad

algo así:

Public Const _Properties As String = "*,Ver{0;Todo;Fondo;Trazo}=Todo,....."


no lo tengo claro, además quiero que en la ide me aparezca un combobox como cuando elegimos alineación, quiero hacer algo parecido

y bien al modificar la propiedad que la voy a llamar "Ver" si ponemos 0 se ven todos los botones, si esta a 1 solo trazo(ocultando el boton fondo) y si 2 solo fondo (ocultando el boton trazo) .....


alguna ayudita?
 




===================
Software libre, programación libre, vida libre es la Public function Libertad()as Invendible
Proyectos: VisorRV1960,Taller2015,Tanteador
https://sourceforge.net/u/v3ctor-full/profile/
Blog: http://novatocodegambas.blogspot.com.uy/
 
última edición por v3ctor el Jueves, 13 Abril 2017, 19:50; editado 2 veces 
v3ctor - Ver perfil del usuarioEnviar mensaje privadoVisitar sitio web del usuario 
Volver arribaPágina inferior
Responder citando   Descargar mensaje  
Mensaje Re: Añadiendo Nuevas Caracteristicas A Control Fbcolor! 
 
bueno esto funciona

cree tres constantes publicas estáticas  vTodo, vTrazo,vFondo

que determinan en la propiedad 'Ver' de tipo byte que botones se ven

y un método que muestra u oculta según el estado de Ver llamado 'ActualizarVista'




' gambas class file

'by Postapase 26 enero 2017
'http://novatocodegambas.blogspot.com.uy/
'control fbcolor  (foreground y background color)

Export

Inherits UserControl

Public Const _Properties As String = "*,Ver=0,Trazo{Color},Fondo{Color},TrazoPredeterminado{Color},FondoPredeterminado{Color},TrazoToolTip,FondoToolTip,ReseteoToolTip"
Public Const _DefaultEvent As String = "Modificacion"
Public Const _DefaultSize As String = "18,4"
Public Const _Group As String = "Chooser"

Static Public Const vTodo As Byte = 0  
Static Public Const vTrazo As Byte = 1
Static Public Const vFondo As Byte = 2

Event Reseteo
Event Modificacion

Property Trazo As Integer
Property Fondo As Integer
Property TrazoPredeterminado As Integer
Property FondoPredeterminado As Integer
Property TrazoToolTip As String
Property FondoToolTip As String
Property ReseteoToolTip As String
Property Ver As Byte

Private $ffbcolor As Ffbcolor
Private $Trazo As Integer
Private $Fondo As Integer
Private $TrazoPredeterminado As Integer
Private $FondoPredeterminado As Integer
Private $TrazoToolTip As String
Private $FondoToolTip As String
Private $ReseteoToolTip As String
Private $Ver As Byte


Public Sub _new()

  $ffbcolor = New Ffbcolor(Me) As "Ev"
  Me.Proxy = $ffbcolor
  $TrazoToolTip = "Color de Trazo (clic para cambiar)"
  $FondoToolTip = "Color de Fondo (clic para cambiar)"
  $ReseteoToolTip = "Poner colores predeterminados"
  Reinicio()
  ActualizarVista()

End

Public Sub ActualizarVista()
  
  Select Case $Ver
    Case 0 ' todo
      $ffbcolor.cbtnFondo.Visible = True
      $ffbcolor.cbtnTrazo.Visible = True
    Case 1 'Solo trazo
      $ffbcolor.cbtnFondo.Visible = False
      $ffbcolor.cbtnTrazo.Visible = True
    Case 2 'solo fondo
      $ffbcolor.cbtnFondo.Visible = True
      $ffbcolor.cbtnTrazo.Visible = False
    Case Else
      $ffbcolor.cbtnFondo.Visible = True
      $ffbcolor.cbtnTrazo.Visible = True
  End Select
  
End



Public Sub Ev_CambioTrazo()

  $Trazo = $ffbcolor.cbtnTrazo.Value
  Raise Modificacion

End

Public Sub Ev_CambioFondo()

  $Fondo = $ffbcolor.cbtnFondo.Value
  Raise Modificacion

End

Public Sub Ev_Reseteo()

  Reinicio()
  Raise Reseteo

End

Public Sub Reinicio()

  $Fondo = $FondoPredeterminado
  $Trazo = $TrazoPredeterminado
  $ffbcolor.cbtnFondo.Value = $Fondo
  $ffbcolor.cbtnTrazo.Value = $Trazo

End

Public Sub Ev_EnterTrazo()

  $ffbcolor.cbtnTrazo.Tooltip = $TrazoToolTip

End

Public Sub Ev_EnterFondo()

  $ffbcolor.cbtnFondo.Tooltip = $FondoToolTip

End

Public Sub Ev_EnterReseteo()

  $ffbcolor.tbtnReseteo.Tooltip = $ReseteoToolTip

End

Private Function Trazo_Read() As Integer

  Return $Trazo

End

Private Sub Trazo_Write(Value As Integer)

  $Trazo = Value
  $ffbcolor.cbtnTrazo.Value = $Trazo
  Raise Modificacion

End

Private Function Fondo_Read() As Integer

  Return $Fondo

End

Private Sub Fondo_Write(Value As Integer)

  $Fondo = Value
  $ffbcolor.cbtnFondo.Value = $Fondo
  Raise Modificacion

End

Private Function TrazoPredeterminado_Read() As Integer

  Return $TrazoPredeterminado

End

Private Sub TrazoPredeterminado_Write(Value As Integer)

  $TrazoPredeterminado = Value
  Raise Modificacion

End

Private Function FondoPredeterminado_Read() As Integer

  Return $FondoPredeterminado

End

Private Sub FondoPredeterminado_Write(Value As Integer)

  $FondoPredeterminado = Value
  Raise Modificacion

End

Private Function TrazoToolTip_Read() As String

  Return $TrazoToolTip

End

Private Sub TrazoToolTip_Write(Value As String)

  $TrazoToolTip = Value

End

Private Function FondoToolTip_Read() As String

  Return $FondoToolTip

End

Private Sub FondoToolTip_Write(Value As String)

  $FondoToolTip = Value

End

Private Function ReseteoToolTip_Read() As String

  Return $ReseteoToolTip

End

Private Sub ReseteoToolTip_Write(Value As String)

  $ReseteoToolTip = Value

End


Private Function Ver_Read() As Byte

  Return $Ver

End

Private Sub Ver_Write(Value As Byte)

  $Ver = Value
  ActualizarVista()
  
End

 




===================
Software libre, programación libre, vida libre es la Public function Libertad()as Invendible
Proyectos: VisorRV1960,Taller2015,Tanteador
https://sourceforge.net/u/v3ctor-full/profile/
Blog: http://novatocodegambas.blogspot.com.uy/
 
v3ctor - Ver perfil del usuarioEnviar mensaje privadoVisitar sitio web del usuario 
Volver arribaPágina inferior
Responder citando   Descargar mensaje  
Mensaje Re: Añadiendo Nuevas Caracteristicas A Control Fbcolor! 
 
aquí   se ven los controles fbcolor

unos usando fondo y trazo y los dos últimos solo fondo ocultando el botón color de trazo

77_1492191479_775303
 




===================
Software libre, programación libre, vida libre es la Public function Libertad()as Invendible
Proyectos: VisorRV1960,Taller2015,Tanteador
https://sourceforge.net/u/v3ctor-full/profile/
Blog: http://novatocodegambas.blogspot.com.uy/
 
v3ctor - Ver perfil del usuarioEnviar mensaje privadoVisitar sitio web del usuario 
Volver arribaPágina inferior
Responder citando   Descargar mensaje  
Mensaje Re: Añadiendo Nuevas Caracteristicas A Control Fbcolor! 
 
v3ctor:

Tendrás que esperar que pase la semana santa. Espero que pronto todo vuelva a la calma y tranquilidad para que podamos escribir.
A penas doy abasto ni a las pregunta que hago.  

Saludos
 




===================
Gambas Básico
“Si no puedes explicar algo de forma sencilla, entonces es que tú no lo entiendes bien.” Albert Einstein
 
Shell - Ver perfil del usuarioEnviar mensaje privadoVisitar sitio web del usuario 
Volver arribaPágina inferior
Responder citando   Descargar mensaje  
Mensaje Re: Añadiendo Nuevas Caracteristicas A Control Fbcolor! 
 
buenas

he encontrado un error en esta clase y consiste en que no toma el value de las propiedades:

fondopredeterminado y trazopredeterminado

es decir antes de arrancar el programa le asigno colores predeterminados en la propiedad en el ide
pero al mostrar solo muestra colores negros que indica que no hay color elegido.

alguna idea de que esta mal?
la clase fbcolor esta en la granja

Saludos
 




===================
Software libre, programación libre, vida libre es la Public function Libertad()as Invendible
Proyectos: VisorRV1960,Taller2015,Tanteador
https://sourceforge.net/u/v3ctor-full/profile/
Blog: http://novatocodegambas.blogspot.com.uy/
 
v3ctor - Ver perfil del usuarioEnviar mensaje privadoVisitar sitio web del usuario 
Volver arribaPágina inferior
Responder citando   Descargar mensaje  
Mensaje Re: Añadiendo Nuevas Caracteristicas A Control Fbcolor! 
 
V3ctor:

Citar:
es decir antes de arrancar el programa le asigno colores predeterminados en la propiedad en el ide
pero al mostrar solo muestra colores negros que indica que no hay color elegido.
alguna idea de que esta mal?

Pues creo que el problema esta es tu constructor  _new() , que llama al método:
 Reinicio()
y este pone valores, que en principio son 0:
Citar:
Public Sub Reinicio()

$Fondo = $FondoPredeterminado
$Trazo = $TrazoPredeterminado
$ffbcolor.cbtnFondo.Value = $Fondo
$ffbcolor.cbtnTrazo.Value = $Trazo

End


Quizas si lo modificas o lo quitas directamente, tomará los valores que pongas en el IDE.... pero no lo he probado.
 




===================
Blog personal
Web: SoloGambas seleccion de articulos dedicados a Gambas
Visita el Curso de Gambas3 ¡¡¡Gratuito!!!
 
jsbsan - Ver perfil del usuarioEnviar mensaje privadoVisitar sitio web del usuario 
Volver arribaPágina inferior
Responder citando   Descargar mensaje  
Mensaje Re: Añadiendo Nuevas Caracteristicas A Control Fbcolor! 
 
justamente ahí esta el problema pues $FondoPredeterminado y  $TrazoPredeterminado
están en blanco cuando deberían tener los valores que se le asignaron en propiedades de la ide

$Fondo = $FondoPredeterminado
$Trazo = $TrazoPredeterminado
 




===================
Software libre, programación libre, vida libre es la Public function Libertad()as Invendible
Proyectos: VisorRV1960,Taller2015,Tanteador
https://sourceforge.net/u/v3ctor-full/profile/
Blog: http://novatocodegambas.blogspot.com.uy/
 
v3ctor - Ver perfil del usuarioEnviar mensaje privadoVisitar sitio web del usuario 
Volver arribaPágina inferior
Mostrar mensajes anteriores:    
 
Ocultar¡Este tema fue útil?

 

Elegir valoración:                       

Media de valoración Valoración mínima Valoración máxima Número de valoraciones
0.00 0 0 0
 
OcultarTemas parecidos
Tema Autor Foro Respuestas último mensaje
No hay nuevos mensajes Controladoras PCI: Añadiendo Mas SATA A ... jsbsan Mundo Linux 13 Domingo, 07 Agosto 2016, 18:55 Ver último mensaje
jsbsan
No hay nuevos mensajes Cosas Nuevas En El IDE tincho Controles/Librerías/Componentes 5 Lunes, 09 Septiembre 2019, 21:57 Ver último mensaje
tincho
No hay nuevos mensajes Nuevas Funciones Y Mejoras De Gambas3.12.0 jsbsan Instalación 11 Miercoles, 09 Enero 2019, 10:43 Ver último mensaje
Shell
No hay nuevos mensajes Creación De Un Nuevo Control En Gambas3: ... jsbsan Videotutoriales 3 Viernes, 06 Febrero 2015, 12:44 Ver último mensaje
jsbsan
 

Publicar nuevo tema  Responder al tema  Página 1 de 1
 

Usuarios navegando en este tema: 0 registrados, 0 ocultos y 1 invitado
Usuarios registrados conectados: Ninguno


 
Lista de permisos
No puede crear mensajes
No puede responder temas
No puede editar sus mensajes
No puede borrar sus mensajes
No puede votar en encuestas
No puede adjuntar archivos
No puede descargar archivos
No puede publicar eventos en el calendario